# Copyright (c) 2018 GitHub, Inc.
# Use of this source code is governed by the MIT license that can be
# found in the LICENSE file.

import("//build/buildflag_header.gni")
import("//electron/buildflags/buildflags.gni")

buildflag_header("buildflags") {
  header = "buildflags.h"

  flags = [
    "ENABLE_VIEWS_API=$enable_views_api",
    "ENABLE_PDF_VIEWER=$enable_pdf_viewer",
    "ENABLE_ELECTRON_EXTENSIONS=$enable_electron_extensions",
    "ENABLE_BUILTIN_SPELLCHECKER=$enable_builtin_spellchecker",
    "OVERRIDE_LOCATION_PROVIDER=$enable_fake_location_provider",
  ]

  if (electron_vendor_version != "") {
    result = string_split(electron_vendor_version, ":")
    flags += [
      "HAS_VENDOR_VERSION=true",
      "VENDOR_VERSION_NAME=\"${result[0]}\"",
      "VENDOR_VERSION_VALUE=\"${result[1]}\"",
    ]
  } else {
    flags += [ "HAS_VENDOR_VERSION=false" ]
  }
}
